1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
/**
 * * tlm.sv 
 * * 说明： 通过简单的模型来阐述 UVM/OVM中TLM uvm_put_port
 * *        和uvm_port_imp直接连接的基本原理。直接编译运行即可。
 * * 作者：Zhu,YH
 */
virtual class port_base#(type T=int) ; // 构造一个抽象类
  typedef port_base#(T) this_type;
  protected this_type port_handle; // 申明一个对象句柄（指针）

  pure virtual task put_t(T trans); // 纯虚函数，put_port和put_imp都必须以它为基类

  function void connect(this_type port); // connect仅仅是实现对象句柄的赋值
    port_handle = port;
  endfunction // connect

endclass // port_base

class put_port#(type T=int) extends port_base#(T);
  virtual task put_t(T trans);
    port_handle.put_t(trans);
  endtask // put_t
endclass // put_port

class put_imp#(type T=int, type IMP=int) extends port_base#(T);
  local IMP m_imp;  // imp表示具体实现put_t()函数的对象句柄。
  function new(IMP imp);
    m_imp = imp;
  endfunction // new

  virtual task put_t(T trans);
    m_imp.put_t(trans);  // 调用实现对象对应的put_t()函数
  endtask // put_t

endclass // put_imp

class producer;
  put_port#(int) m_put_port;
  function new();
    m_put_port = new();
  endfunction // new

  task run();
    for(int i=0; i<10; i++) begin  // 顺序产生10个int类型的transaction.
      m_put_port.put_t(i);
    end
  endtask // run
endclass // producer

class consumer;
  put_imp#(int, consumer)  m_put_export;
  function new();
    m_put_export = new(this); //将consumer句柄传递给put_imp中imp变量，从而实现接管put_t()最终实现
  endfunction // new

  task put_t(int trans);
    $display("[INFO]: Got the transaction:%d", trans);
  endtask // put_t
endclass // consumer

module top;
  producer p;
  consumer c;
  initial begin
    p = new();
    c = new();
    p.m_put_port.connect(c.m_put_export);  //通过句柄赋值进行连接
    p.run();
    #10 $finish;
  end
endmodule